Регулярное выражение Perl: как узнать количество совпадений

Если вы выполняете сопоставление в контексте списка (т. е., по сути, присваиваете списку), вы получаете все свои совпадения и группировки в списке. Затем вы можете просто использовать этот список в скалярном контексте, чтобы получить количество совпадений.

Или я неправильно понимаю вопрос?

Пример:

my @list = /$my_regex/g;
if (@list)
{
  # do stuff
  print "Number of matches: " . scalar @list . "\n";
}

Вам нужно будет следить за этим самостоятельно. Вот один из способов сделать это:

#!/usr/bin/perl

use strict;
use warnings;

my @regexes = (
    qr/b/,
    qr/a/,
    qr/foo/,
    qr/quux/,
);

my %matches = map { $_ => 0 } @regexes;
while (my $line = <DATA>) {
    for my $regex (@regexes) {
        next unless $line =~ /$regex/;
        $matches{$regex}++;
    }
}

for my $regex (@regexes) {
    print "$regex matched $matches{$regex} times\n";
}

__DATA__
foo
bar
baz

При обработке CA::Parser связанные с совпадениями для /$CA::Regex::Parser{Kills}{all}/, вы используете захваты $1 на протяжении всего $10, а большинство остальных используют меньше. Если под количеством совпадений вы подразумеваете количество захватов (наибольшее значение n, для которого $n имеет значение), вы можете использовать специальный массив Perl @- (выделение добавлено):

@LAST_MATCH_START

@-

$-[0] — это смещение начала последнего успешного совпадения. $-[n] — это смещение начала подстроки, совпавшей с n-м подшаблоном, или undef, если подшаблон не совпал. Таким образом, после матча с $_ $& совпадает с substr $_, $-[0], $+[0] - $-[0]. Точно так же $n совпадает с

substr $_, $-[n], $+[n] - $-[n]

если $-[n] определено, а $+ совпадает с

substr $_, $-[$#-], $+[$#-] - $-[$#-]

Можно использовать $#-, чтобы найти последнюю совпавшую подгруппу в последнем успешном совпадении. В отличие от $#+, количества подгрупп в регулярном выражении. Сравните с @+.

Этот массив содержит смещения начала последних успешных подсовпадений в текущей активной динамической области. $-[0] — это смещение в строке начала всего совпадения. n-й элемент этого массива содержит смещение n-го подсовпадения, поэтому $-[1] — это смещение, где начинается $1, $-[2] — смещение, где начинается $2, и так далее.

После совпадения с некоторой переменной $var:

• $` совпадает с substr($var, 0, $-[0])
• $& совпадает с substr($var, $-[0], $+[0] - $-[0])
• $' совпадает с substr($var, $+[0])
• $1 совпадает с substr($var, $-[1], $+[1] - $-[1])
• $2 совпадает с substr($var, $-[2], $+[2] - $-[2])
• $3 совпадает с substr($var, $-[3], $+[3] - $-[3])

Пример использования:

#! /usr/bin/perl

use warnings;
use strict;

my @patterns = (
  qr/(foo(bar(baz)))/,
  qr/(quux)/,
);

chomp(my @rawfile = <DATA>);

foreach my $pattern (@patterns) {
  LINE: for (@rawfile) {
    /$pattern/ && do {
      my $captures = $#-;
      my $s = $captures == 1 ? "" : "s";
      print "$_: got $captures capture$s\n"; 
    };
  }
}

__DATA__
quux quux quux
foobarbaz

Вывод:

foobarbaz: got 3 captures
quux quux quux: got 1 capture

Как насчет кода ниже:

my $string = "12345yx67hjui89";    
my $count = () = $string =~ /\d/g;
print "$count\n";

Он печатает 9 здесь, как и ожидалось.